resource "bunnynet_pullzone" "r-package-binaries-docs" {

  name = "r-package-binaries-docs"

  origin {
    type = "OriginUrl"
    url  = "https://devxy-r-package-binaries-docs.fsn1.your-objectstorage.com"
  }

  routing {
    tier = "Standard"
  }

  s3_auth_enabled = true
  s3_auth_key     = var.HETZNER_S3_ACCESS_KEY_K3S
  s3_auth_secret  = var.HETZNER_S3_SECRET_KEY_K3S
  s3_auth_region  = "fsn1"

  cache_enabled = true
  cache_errors  = true
  # 3 months (override origin cache policy which is 30d)
  cache_expiration_time = 7776000
  # not so great in case data from users is being sent (at some point)
  request_coalescing_enabled = false
  block_post_requests        = true

  originshield_enabled           = true
  originshield_concurrency_limit = true
  originshield_zone              = "FR"

  safehop_enabled = true

  # otherwise this will expose the S3 origin URL as a secondary canonical URL
  add_canonical_header = false

  block_root_path = false

  # FIXME: https://github.com/BunnyWay/terraform-provider-bunnynet/issues/19
  log_forward_server = "127.0.0.1"
}

resource "bunnynet_pullzone_hostname" "r-package-binaries-docs" {

  pullzone    = bunnynet_pullzone.r-package-binaries-docs.id
  name        = "docs.r-package-binaries.devxy.io"
  force_ssl   = true
  tls_enabled = true
}